Tutorial Example

From BioNetWiki

This is the BNGL for the example I presented at the 2006 RTK Workshop.

# Example file for BNG2 tutorial.
# All text following the occurence off '#' character in a line is ignored.
#   Written by James R. Faeder
#	       Theoretical Biology and Biophysics Group
#	       Los Alamos National Laboratory
#	       faeder@lanl.gov	       
#   10/28/2005

begin parameters
  1 L0   200	# Number of ligand molecules
  2 R0   200	# Number of receptor molecules
  3 A0   50	# Number of adaptor molecules
  4 kp1  0.01	# Ligand-receptor association
  5 km1  1	# Ligand-receptor dissociation
  6 kp2  1	# Dimer formation
  7 km2  1	# Dimer dissociation
  8 p1  10	# Receptor transphosphorylation
  9 d1   5	# Receptor dephosphorylation
 10 kpA  0.1	# Adaptor-receptor association
 11 kmA  0.1	# Adaptor-receptor dissociation
 12 p2   10	# Adaptor transphosphorylation
 13 d2    5	# Adaptor dephosphorylation
end parameters

begin species
  1  L(r)       L0
  2  R(l,d,Y~U) R0
  3  A(SH2,Y~U)     A0
end species

begin observables
  Molecules R_dim  R(d!+)
  Molecules R_phos R(Y~P!?)
  Molecules A_R    A(SH2!1).R(Y~P!1)
  Molecules A_phos A(Y~P!?)
end observables

begin reaction rules
  1  L(r) + R(l,d) <-> L(r!1).R(l!1,d) kp1, km1
  2  R(l!+,d) + R(l!+,d) <-> R(l!+,d!2).R(l!+,d!2) kp2, km2
  3  R(d!+,Y~U) -> R(d!+,Y~P) p1 
  4  R(Y~P) -> R(Y~U) d1
  5  R(Y~P) + A(SH2) <-> R(Y~P!1).A(SH2!1) kpA, kmA
  6  A(Y~U).A() -> A(Y~P).A() p2
  7  A(Y~P) -> A(Y~U) d2
end reaction rules

generate_network({overwrite=>1});
writeSBML();
simulate_ode({t_end=>5,n_steps=>50});
#simulate_ssa({t_end=>5,n_steps=>50});